Processing 入門 Lesson 19 【スイッチとLED】

Processing 入門
Lesson 19
【スイッチとLED】

こんにちは、管理人のomoroyaです。

Lesson 18は【サーボモーターとコントローラー】ということでProcessingで簡易的なコントローラーを作成し、サーボモーターと連携しました。

Lesson 19は【スイッチとLED】です。

今までは「Processing」　→　「Arduino」という情報の流れでした。

本Lessonからは逆の流れを学習していきます。

「Arduino」　→　「Processing」

というわけです。

Arduinoので取得したデータをProcessingで処理する学習となります。

まずは、理解しやすいように「プッシュボタンスイッチ」と「LED」のみを使った回路で学習していきましょう。

Processing学習の最終目標は、「6軸モーションセンサ」との連携です。

Lesson 14以降を学習することでLesson 01 ～ Lesson 06【Arduino連携変そのX】で遊んだスケッチも理解できるようになるはず。

これからのLessonを楽しみましょう！

Processingを始めようと考えている方。

ネット情報のみでも十分に学習可能です。

手元に参考書がほしいと考えている場合は下記の2冊程度で十分と考えます。

Processingをはじめよう第2版 (Make: PROJECTS)

オライリージャパン

東京電機大学出版局

はじめに
Lesson 19 目標
本Lessonの学習に必要な物
実践回路作成
1. 回路図
2. 接続
Serial入出力のためのクラス復習
実践スケッチ作成
まとめ
最後に
Amazonでお得に買う方法

はじめに

Lesson 14からはArduinoと一緒に学習していきます。

Arduinoの詳細な解説は「Arduino入門編」にて確認してください。

Arduino入門編

Arduino入門の記事となります。購入編から、IDEの使い方、色々な電子部品を使った実践編まで幅広く解説しています。また、サンプルのスケッチ（コード）は詳細に説明しています。初めてのかたでも、スケッチ（コード）を理解できます！Arduin…

本LessonではプッシュボタンスイッチでLEDをON,OFFさせます。

その、ON、OFFの情報をArduinoからパソコンへ送信し、Processingで処理して画像で表現するということになります。

「プッシュボタンスイッチって何？」というう場合は、下記を読んでおくと理解しやすいはずです。

Arduino 入門 Lesson 05 【プッシュボタンスイッチ編】

このLessonでは、機械的にスイッチを使ってLEDをオン、オフさせるわけではありません。スイッチを「押した」「押してない」という行為をデジタル信号としてUNOに認識させるということです。それによって、UNOから電源が供給されLEDのオン、…

Lesson 19 目標

本Lessonの目標は以下の2点です。

1．Arduino →　Processingの通信方法を理解
2．プッシュボタンスイッチとLEDの復習

本Lessonの学習に必要な物

本Lessonに必要となる電子部品を列挙します。

USB接続用のPC（IDE統合環境がインストールされたPC）
→管理人が勝手に比較したBTOメーカーを紹介しています。
UNO R3(以下UNO)、おすすめUNO互換品（ELEGOO）
PCとUNOを接続するUSBケーブル
ブレッドボード安価（大）、ブレッドボード安価（中）
※おすすめブレッドボード（大）、おすすめブレッドボード（中）
抵抗 220Ω 1本
押しボタン式のスイッチ 2個
※プッシュスイッチ、タクトスイッチとも呼ばれます。
M-M Jumper wire（UNOと部品をつなぐための配線）

Jumper wireはできれば、「オス-メスオス-オスメス –メス」の３種類を揃えておくことをお勧めします。

ELEGOO 120pcs多色デュポンワイヤー、arduino用ワイヤ—ゲ—ジ28AWG オス-メスオス-オスメス –メスブレッドボードジャンパーワイヤー

ELEGOO

短めのメスーオスが使いやすい場合も。

uxcell ジャンプワイヤコネクタラインジャンパーケーブル 1P-1P 40P 10cm メスオス

uxcell

抵抗、LEDなどを個別でセット品を購入しても、そんなに使わない！

という方は、「電子工作基本部品セット」が使い勝手が良い。

OSOYOO(オソヨー) 電子工作基本部品セット LED 5色合計100PCS 金属皮膜抵抗器 30種類合計600本電解コンデンサ 12種類合計120本セラミックコンデンサー 30種類合計300本ダイオード 8種類合計100本トランジスタ 17種類合計170本 (電子部品セット6種類)

OSOYOO

実践回路作成

最初に回路図を確認してください。

次に、回路図に合わせて部品を接続します。

最後にスケッチ（コード）を描きましょう。

プッシュボタンスイッチでLEDを点灯、消灯、Processingで点灯、消灯を表現していきます。

Arduinoのピン配置を確認したい方は番外編02を参照してください。

Arduino 入門番外編 02 【外観とピン配置】

本日は、番外編02 Arduino UNO R3 外観とピン配置です。arduinoの入門編を書いていて、arduino自体の説明をしたいと考えていました。やはり、arduino自身のことを理解しておいた方が良いですよね。ということで番外編…

回路図

プッシュボタンスイッチとLED、抵抗のみの回路となります。

Arduino 入門 Lesson 05 【プッシュボタンスイッチ編】と同じ回路です。

利用するピンも同じ５、8、9番ピン。

回路図がこちら。

こちらがブレッドボード図。

回路図は「fritzing」を利用しています。

「fritzing」の使い方は下記を参照してください。

Arduino 入門番外編 01 【回路図を書こう fritzing】

UNOの実際の回路を写真で掲載しても、接続がわかりずらいかなと考えていました。前々から「fritzing」を利用して回路を描くことで、わかりやすくしたいと考えていました。そこで本日は、「fritzing」のインストールと回路図を描くことに挑…

接続

下図に示すように、用意した部品を使用して接続しましょう。

部品はプッシュボタンスイッチとLED、抵抗のみのため簡単に接続できます。

使用するポートは、Digital IOの「５、８、９」電源の「5V」「GND」です。

穴に挿入しづらいときは、ラジオペンチなどを使用してください。

Serial入出力のためのクラス復習

Lesson 14にて解説しましたが、覚えるという意味で再度軽く解説。

Serialクラスの機能を使うためには、「serialパッケージをimport」する。

import processing.serial.*;

次に、Serialオブジェクトの生成処理。

生成するためには、Serialクラスのコンストラクタ使用。

Serial(parent, portName, baudRate);
parent：通常「this」を使用
portName：ポート番号（COM*）　デフォルト：COM1
baudRate：通信速度　デフォルト：9600

使用例
Serial Port; //シリアルクラスのオブジェクト、変数の設定
Port = Serial(this, COM3, 9600); //Serialオブジェクト生成、Portへ代入

Serialクラスの主なメソッドを紹介。

Serialクラス	内容
available()	読めるデータのバイト数を返す。戻り値が0より大きい場合、データを利用できる。
serial.list()	使用可能なシリアルポートのリストを返す。
read()	次の1バイトの読み込み。 0～255の値を返す。読めるバイトがないと-1を返す。データが使用可能かどうかを確認するために最初にavailable()で確認することを推奨します。
write()	バイト、文字、整数、バイト[]、文字列をシリアルポートに書き込みます。

詳しく知りたい方は、公式のホームページで確認！

Serial / Libraries

Send data between Processing and external hardware through serial communication (RS-232).…

実践スケッチ作成

ProcessingとArduinoを連携するためには、お互いにデータのやり取りをする必要があります。

本Lessonのデータのやり取りは、「Arduino」　→　「Processing」。

Lesson18までとは逆方向になります。

プッシュボタンスイッチを押すことでLEDをON、OFFする。

プッシュボタンスイッチを押したことをパソコン側へ伝える。（送信）

Processingウィンドウでも同じようにON、OFFがわかるグラフィックを描画。

といった動作になります。

Arduino側は、スイッチのON、OFFで変わるPINの情報をパソコンへ送信。

８、９番ピンの状態をSerial.write()関数で送信

Processing側のスケッチは送られてきたデータによってグラフィックを描画。

送られてきたデータをread()関数で読み込みグラフィックを表示

Arduino用　サンプルスケッチ

サンプルスケッチ（コード）を下記に示します。

デジタル入出力である５、８、9番ピンを使用します。

次に8、９番ピンの状態によってLEDを点灯消灯。

あわせてProcessingへ「a」または「b」のデータを送信するスケッチとなります。

//Lesson 19 Processing制御用のArduino用スケッチ
//ProcessingによるLED ON/OFF の描画
//https://omoroya.com/

int ledPin = 5;     //デジタルピン5にLED（陽極）を割り当て
int buttonApin = 9; //デジタルピン9にプッシュボタンAに割り当て
int buttonBpin = 8; //デジタルピン8にプッシュボタンBを割り当て

void setup() {
  Serial.begin(9600); //シリアル通信のデータ転送レートを設定しポート開放
  pinMode(ledPin, OUTPUT);           //5番ピンをOUTPUTに設定
  pinMode(buttonApin, INPUT_PULLUP); //9番ピンをHighにする（プルアップ）
  pinMode(buttonBpin, INPUT_PULLUP); //8番ピンをHighにする（プルアップ）
}

void loop() {
  
  if (digitalRead(buttonApin) == LOW){ //9番ピンがLowなら｛ ｝内を実行
    digitalWrite(ledPin, HIGH);        //LEDにHighを送る(ON)
    Serial.write('a');                 //「a」を送信
    delay(100);
  }

  if (digitalRead(buttonBpin) == LOW){ //8番ピンがLowなら｛ ｝内を実行
    digitalWrite(ledPin, LOW);         //LEDにLowを送る(OFF)
    Serial.write('b');                 //「b」を送信
    delay(100);
  }
}

このスケッチはProcessingがなくても動作を確認することができます。

Aruduinoのシリアルモニタを立ち上げて、プッシュボタンスイッチを押してみてください。

シリアルモニタに押したスイッチにあわせて「a」または「b」が表示されるはずです。

シリアルモニタに表示されるデータをProcessing側へ送っているということです。

Processing用　サンプルスケッチ

サンプルスケッチ（コード）を下記に示します。

このスケッチで重要なところは、新しく使用した関数「serialEvent()関数」でしょうか。

Arduinoから「a」「b」のデータが送られてくると変数「c」に格納するようにしています。

serialEvent()：Processingがデータを受信した際に発生するイベント構文
void serialEvent(Serial whichPort) {
有効なステートメント;
}Serial: 新しいデータが有効可能なポート

width、height
ウィンドサイズのサイズ値が入っているということも覚えておくと図形描画に便利！

//Lesson 19 Processing用スケッチ
//ProcessingによるLED ON/OFF の描画
//https://omoroya.com/

import processing.serial.*; //Arduinoと通信するためのライブラリの読み込み
Serial myPort;              //シリアル通信を行うための変数を定義
PFont  myFont;              //画面に表示するフォントの指定

int c;                      //グローバル変数の設定
int w = 300, h = 300;       //円のサイズ

void setup() {
  size(400, 400);                         //ウィンドウサイズ
  background(200);                        //背景の色
  
  println("Available serial ports:");
  printArray(Serial.list());              //使用できるCOMポートの取得
  //printArray(PFont.list());             //使用できるFontの表示、わからないときに使用
  
  myPort = new Serial(this, Serial.list()[0], 9600); //通信するポートと速度の設定、Arduinoと合わせる必要あり
  myFont = createFont("Meiryo UI Bold", 100);        //Font指定、サイズ100pt
  textFont(myFont);
  
  textAlign(CENTER);                 //文字揃え、中心
  stroke(0);                         //線の色を黒
  fill(0);                           //塗りつぶし色を黒
  myPort.clear();                    //受信データをクリア
  ellipse(width/2, height/2, w, h);  //円を表示
  fill(255, 255, 0);                 //文字を黄色
  text("OFF", width/2, height/2+50); //テキストを中心に表示
}

void draw() {
  if (c == 'a'){                       //受信データが「a」の場合
    fill(255, 0, 0);                   //赤色へ
    ellipse(width/2, height/2, w, h);  //円を表示
    fill(255, 255, 0);                 //文字を黄色
    text("ON", width/2, height/2+50);  //テキストを中心に表示
  }
  else if (c == 'b'){                  //受信データが「b」の場合
    fill(0, 0, 0);                     //黒色へ
    ellipse(width/2, height/2, w, h);  //円を表示
    fill(255, 255, 0);                 //文字を黄色
    text("OFF", width/2, height/2+50); //テキストを中心に表示
  }
}

void serialEvent(Serial myPort) {      //データを受信した際に発生するイベント
    c = myPort.read();                 //データを読み込む
}

※serialEvent関数の「myPort」は別名でもかまいません。
わかりやすくるるために合わせています。

補足事項
通信速度、COMポートの番号はArduinoと合わせる必要があります。
COMポートはAruduinoがつながっている番号であり、デバイスマネージャで確認可能。